---
sourceDocument: 호주 IT Operations Management
sourceDocumentLink: https://servicenow-prod.fluidtopics.net/r/ko-KR/it-operations-management

 Release :

    - australia

ft:locale :

    - ko-KR

ft:publication_title :

    - 호주 IT Operations Management

ft:clusterId :

    - itom

bundleId :

    - itom

workflow :

    - Technology


---

# Terraform 템플릿 게시

# Terraform 템플릿 게시 {#ariaid-title1}

* 릴리스 버전: Australia
* 
* 업데이트 날짜 2026년 03월 12일
* 
* ![](https://www.servicenow.com/docs/portal-asset/ico-clock) 소요 시간: 4분

Terraform 에서 애플리케이션에서 GitHub 정의한 템플릿을 게시하여 버전 제어, 공동 작업 및 중앙 집중식 스토리지를 사용하도록 설정합니다.

## 시작하기 전에

필요한 역할: Terraform 관리자

## 프로시저

1. Terraform 템플릿 전용 GitHub 리포지토리를 만듭니다.
2. 다음 코드를 별도의 파일에 저장합니다.  
   * 파일 이름: awsaccount.tf

         terraform {
           required_providers {
             aws = {
               source  = "hashicorp/aws"
               version = "~>5.0"
             }
           }
         }

         provider "aws" {
           region = var.region
         }

         resource "aws_organizations_account" "account" {
           email = var.root_email
           name = var.account_name
           tags = var.tags
           parent_id = var.parent_id
           close_on_deletion=var.close_delete
           create_govcloud=var.gov_cloud
         }

         resource "aws_budgets_budget" "cost" {
           name  = join("-", ["SN-CAM-Monthly-Budget", aws_organizations_account.account.id])
           count = var.monthly_budget > 0 ? 1 : 0
           budget_type  = "COST"
           limit_amount = var.monthly_budget
           limit_unit   = "USD"
           time_unit    = "MONTHLY"

           cost_filter {
             name = "LinkedAccount"
             values = [
               aws_organizations_account.account.id
             ]
           }

           notification {
             comparison_operator        = "GREATER_THAN"
             threshold                  = 100
             threshold_type             = "PERCENTAGE"
             notification_type          = "FORECASTED"
             subscriber_email_addresses = [var.root_email, var.notification_email]
           }

           notification {
             comparison_operator        = "GREATER_THAN"
             threshold                  = 85
             threshold_type             = "PERCENTAGE"
             notification_type          = "ACTUAL"
             subscriber_email_addresses = [var.root_email, var.notification_email]
           }

           notification {
             comparison_operator        = "GREATER_THAN"
             threshold                  = 100
             threshold_type             = "PERCENTAGE"
             notification_type          = "ACTUAL"
             subscriber_email_addresses = [var.root_email, var.notification_email]
           }
         }

   * 파일 이름: variables.tf

         variable "region" {
           type = string
           default = "us-east-1"
         }

         variable "account_name" {
           type = string
           description = "(Required) Account Name"
         }

         variable "root_email" {
           type = string
           description = "(Required) Account Email"
         }

         variable tags{
           type = map(string)
           description = "(Required) Tags for the resource"
         }

         variable "close_delete" {
           type = bool
           description = "Close Account on deletion"
           default = true
         }

         variable "gov_cloud" {
           type = bool
           description = "Gov Cloud Account"
           default = false
         }

         variable "parent_id" {
           type = string
           description = "(Required) Account Parent Organizational Unit"
         }

         variable monthly_budget {
           type = number
           default = 0
         }

         variable notification_email {
           type = string
           description = "Additional email where Budget Notifications are to be sent"
         }

   {#publish-terraform-templates__ul_uqh_hcm_lcc}
3. Terraform 파일을 원격 리포지토리로 푸시합니다.
4. 템플릿이 GitHub에 저장되면 위치 또는 URL을 기록해 둡니다.  
   그런 다음, 이 템플릿을 Terraform Cloud 및 ServiceNow 인스턴스에서 참조하여 구독 계정 생성을 자동화합니다.  
   중요사항:  
   변수가 애플리케이션에 밀접하게 연결되어 있으므로 템플릿을 수정하지 마십시오.
**관련 태스크**   

* [Terraform 에 대한 클라우드 계정 관리 조직 생성클라우드 작업 공간](https://servicenow-prod.fluidtopics.net/U2_KceAWkF0favwUAy~NNw "/Terraform Enterprise와 통합하여 계정을 구성하고, 워크플로우를 정의하고, 보안을 적용하고, 공동 작업을 개선하고, 확장성을 Terraform Cloud향상시킵니다.")
* [Terraform Cloud와 GitHub 통합](https://servicenow-prod.fluidtopics.net/gAVM2ye2s6K0j_GUhqGM4Q "와 Terraform 통합하여 GitHub 작업 공간을 리포지토리에 연결하고 버전 제어, 변경 내용 추적 및 롤백을 활성화합니다.")
* [Terraform API 토큰 생성](https://servicenow-prod.fluidtopics.net/tcjCpDXSGbQomeOn5TDNUA "제한된 권한으로 API 토큰을 생성하면 보안이 강화되고, 세분화된 제어가 가능하며, 자동화가 용이해지고, 조직 내에서 Terraform 임시 액세스가 제공됩니다.")