---
sourceDocument: Gestion des opérations IT Australie
sourceDocumentLink: https://servicenow-prod.fluidtopics.net/r/fr-FR/it-operations-management

 Release :

    - australia

ft:locale :

    - fr-FR

ft:publication_title :

    - Gestion des opérations IT Australie

ft:clusterId :

    - itom

bundleId :

    - itom

workflow :

    - Technology


---

# Publier des Terraform modèles

# Publier des Terraform modèles {#ariaid-title1}

* Rversion finale: Australia
* 
* Mis à jour 12 mars 2026
* 
* ![](https://www.servicenow.com/docs/portal-asset/ico-clock) 1 minute de lecture

Publiez le modèle défini par l'application dans GitHub pour activer le contrôle de version, la collaboration et le Terraform stockage centralisé.

## Avant de commencer

Rôle requis : Terraform admin

## Procédure

1. Créez un GitHub référentiel dédié à vos Terraform modèles.
2. Enregistrez les codes suivants dans un fichier séparé.  
   * Nom du fichier : awsaccount.tf

         terraform {
           required_providers {
             aws = {
               source  = "hashicorp/aws"
               version = "~>5.0"
             }
           }
         }

         provider "aws" {
           region = var.region
         }

         resource "aws_organizations_account" "account" {
           email = var.root_email
           name = var.account_name
           tags = var.tags
           parent_id = var.parent_id
           close_on_deletion=var.close_delete
           create_govcloud=var.gov_cloud
         }

         resource "aws_budgets_budget" "cost" {
           name  = join("-", ["SN-CAM-Monthly-Budget", aws_organizations_account.account.id])
           count = var.monthly_budget > 0 ? 1 : 0
           budget_type  = "COST"
           limit_amount = var.monthly_budget
           limit_unit   = "USD"
           time_unit    = "MONTHLY"

           cost_filter {
             name = "LinkedAccount"
             values = [
               aws_organizations_account.account.id
             ]
           }

           notification {
             comparison_operator        = "GREATER_THAN"
             threshold                  = 100
             threshold_type             = "PERCENTAGE"
             notification_type          = "FORECASTED"
             subscriber_email_addresses = [var.root_email, var.notification_email]
           }

           notification {
             comparison_operator        = "GREATER_THAN"
             threshold                  = 85
             threshold_type             = "PERCENTAGE"
             notification_type          = "ACTUAL"
             subscriber_email_addresses = [var.root_email, var.notification_email]
           }

           notification {
             comparison_operator        = "GREATER_THAN"
             threshold                  = 100
             threshold_type             = "PERCENTAGE"
             notification_type          = "ACTUAL"
             subscriber_email_addresses = [var.root_email, var.notification_email]
           }
         }

   * Nom du fichier : variables.tf

         variable "region" {
           type = string
           default = "us-east-1"
         }

         variable "account_name" {
           type = string
           description = "(Required) Account Name"
         }

         variable "root_email" {
           type = string
           description = "(Required) Account Email"
         }

         variable tags{
           type = map(string)
           description = "(Required) Tags for the resource"
         }

         variable "close_delete" {
           type = bool
           description = "Close Account on deletion"
           default = true
         }

         variable "gov_cloud" {
           type = bool
           description = "Gov Cloud Account"
           default = false
         }

         variable "parent_id" {
           type = string
           description = "(Required) Account Parent Organizational Unit"
         }

         variable monthly_budget {
           type = number
           default = 0
         }

         variable notification_email {
           type = string
           description = "Additional email where Budget Notifications are to be sent"
         }

   {#publish-terraform-templates__ul_uqh_hcm_lcc}
3. Poussez les Terraform fichiers vers le référentiel distant.
4. Notez l'emplacement ou l'URL une fois que le modèle est stocké dans le GitHub fichier .  
   Ce modèle est ensuite référencé dans Terraform Cloud et l'instance ServiceNow pour automatiser la création d'un compte d'abonnement.  
   Important :  
   Ne modifiez pas le modèle, car les variables sont étroitement liées à l'application.
**Tâches associées**   

* [Créer une Terraform organisation pour Gestion des comptes cloud dans Espace de travail dans le cloud](https://servicenow-prod.fluidtopics.net/umWaTPF3sbwX8~AuUopSBA "Intégrer avec Terraform Cloud/Terraform Enterprise pour organiser les comptes, définir les workflows, appliquer la sécurité, améliorer la collaboration et accroître l’évolutivité.")
* [Intégrer Terraform Cloud à GitHub](https://servicenow-prod.fluidtopics.net/UF0oY0J2L~00eu4~LOmzuA "Intégrez GitHubTerraform pour lier les espaces de travail aux référentiels, permettant ainsi le contrôle de version, le suivi des changements et les restaurations.")
* [Créer un Terraform jeton d'API](https://servicenow-prod.fluidtopics.net/S3ymCp0RWzHgUgYDrnCj6w "La génération de jetons d’API avec des autorisations limitées renforce la sécurité, permet un contrôle précis, facilite l’automatisation et fournit un accès temporaire au sein de votre Terraform organisation.")